plugins {
    `java-library`
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.kotlin.plugin.serialization)
}

kotlin {
    compilerOptions.jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_11)
}
java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

dependencies {
    api(libs.kotlinx.serialization.json)
    api(platform(libs.okhttp.bom))
    implementation(libs.okhttp)
    api("org.jetbrains.kotlinx:kotlinx-coroutines-core:${libs.versions.kotlinxCoroutinesTest.get()}")
    testImplementation(libs.junit)
    testImplementation("com.squareup.okhttp3:mockwebserver3")
}

sourceSets.test { resources.srcDir("openapi") }

val smoke by tasks.registering(JavaExec::class) {
    dependsOn(tasks.testClasses)
    classpath = sourceSets.test.get().runtimeClasspath
    mainClass.set("org.justinvisser.wolfskin.conductarr.ClientSmokeKt")
    mustRunAfter(tasks.test)
}

// The root gate selects this name across all projects, including this JVM module.
tasks.register("testDefaultDebugUnitTest") {
    dependsOn(tasks.test, smoke)
}